循环结构
　　　　循环结构允许重复执行一行或数行代码。Visual Basic 支持的循环结构有：
　　　　1.Do...Loop
　　　　2.For...Next
　　　　3.For Each...Next

　　　　Do...Loop
　　　　用 Do 循环重复执行一语句块，且重复次数不定。Do...Loop 语句有几种演变形式，但每种都计算数值条件以决定是否继续执行。如同 If...Thencondition 必须是一个数值或者值为 True（非零）或 False（零）的表达式。在下面的 Do...Loop 循环中，只要 condition 为 True 就执行 statements。
　　　　Do While condition
　　　　　　　statements

　　　　Loop
　　　　当 Visual Basic 执行这个 Do 循环时会首先测试 condition。如果 condition为 False（零），则跳过所有语句。如果 condition 为 True（非零），则 VisualBasic 执行语句，然后退回到 Do While 语句再测试条件。
　　　　因此，只要 condition 为 True 或非零，循环可以随意执行多少次。如果condition 一开始便为 False，则不会执行语句。例如，以下过程将计算某一目标字符串在另一字符串中出现的次数，只要发现目标串就执行循环：
　　　　Function CountStrings (longstring, target)
　　　　　　　　Dim position, count
　　　　　　　　position = 1
　　　　　　　　Do While InStr (position, longstring, target)
　　　　　　　　　　　position = InStr(position, longstring, target)_
　　　　　　　　　　　　+ 1
　　　　　　　　　　　　count = count + 1
　　　　　　　　Loop
　　　　　　　　CountStrings = count
　　　　End Function
　　　　如果目标字符串未出现在另一个字符串中，则 InStr 返回 0，而且不再执行循环。
　　　　Do...Loop 语句的另一种演变形式是先执行语句，然后在每次执行后测试condition。这种形式保证 statements 至少执行一次：
　　　　Do
　　　　　　　statements
　　　　Loop While condition
　　　　其它两种演变形式类似于前两个，所不同的是，只要 condition 为 False 而不是 True，它们就执行循环。

　　　　For...Next000
　　　　在不知道循环内需要执行多少次语句时，宜用 Do 循环。但是，在知道要执行多少次时，则最好使用 For...Next 循环。与 Do 循环不同， For 循环使用一个叫做计数器的变量，每重复一次循环之后，计数器变量的值就会增加或者减少。For 循环的语法如下：
　　　　For counter = start To end [Step increment]
　　　　　　statements
　　　　Next [counter]
　　　　参数 Counter、Start、end 和 increment 都是数值型的。
　　　　注意 increment 参数可正可负。如果 increment 为正，则 Start 必须小于等于end，否则不能执行循环内的语句。如果 increment 为负，则 Start 必须大于等于 end，这样才能执行循环体。如果没有设置 Step，则 increment 缺省值为 1。
　　　　在执行 For 循环时，Visual Basic
　　　　1. 设置 counter 等于 start。
　　　　2. 测试 counter 是否大于 end。若是的话，则 Visual Basic 退出循环。 （若 increment 为负，则 Visual Basic 测试 counter 是否小于 end。）
　　　　3. 执行语句。
　　　　4. counter 增加一，或者增加 increment（如果已指定的话）。
　　　　5. 重复步骤 2 到步骤 4。
　　　　以下代码打印出所有有效的屏幕字体名：
　　　　Private Sub Form_Click ()
　　　　　　　Dim I As Integer
　　　　　　　For i = 0 To Screen.FontCount
　　　　　　　　　Print Screen.Fonts (i)
　　　　　　　Next
　　　　End Sub
　　　　在 VCR 示例应用程序中，HighlightButton 过程使用 For...Next 循环，一步步经过 VCR 窗体的控件集合，并显示适当的 Shape 控件：
　　　　Sub HighlightButton (MyControl As Variant)
　　　　　　　Dim i As Integer
　　　　　　　For i = 0 To frmVCR.Controls.Count - 1
　　　　　　　　　　If TypeOf frmVCR.Controls (i) Is Shape Then
　　　　　　　　　　　　If frmVCR.Controls (i).Name = MyControl Then
　　　　　　　　　　　　　　　frmVCR.Controls (i).Visible = True
　　　　　　　　　　　　Else
　　　　　　　　　　　　　　　frmVCR.Controls (i).Visible = False
　　　　　　　　　　　　End If
　　　　　　　　　　End If
　　　　　　　Next
　　　　End Sub

　　　　For Each...Next
　　　　For Each...Next 循环与 For...Next 循环类似，但它对数组或对象集合中的每一个元素重复一组语句，而不是重复语句一定的次数。如果不知道一个集合有多少元素， For Each...Next 循环非常有用。
　　　　For Each...Next 循环的语法如下：
　　　　For Each element In group
　　　　　　statements
　　　　Next elementt
　　　　例如，下面的子过程打开 Biblio.mdb，把每一个表的名字加到列表框中。
　　　　Sub ListTableDefs ()
　　　　　　Dim objDb As Database
　　　　　　Dim MyTableDef as TableDef
　　　　　　Set objDb = OpenDatabase("c:\vb\biblio.mdb", _
　　　　　　True, False)
　　　　　　For Each MyTableDef In objDb.TableDefs ()
　　　　　　　　List1.AddItem MyTableDef.Name
　　　　　　　　Next MyTableDef
　　　　　　End Sub
　　　　请记住使用 For Each...Next 时的几点限制：
　　　　1.对集合，element 只能是 Variant 变量，或一般的 Object 变量，或“对象浏览器”中列出的对象。
　　　　2.对数组，element 只能是 Variant 变量。
　　　　3.For Each...Next 不能与用户自定义类型的数组一起使用，因为 Variant 不可能包含用户自定义类型。

　　　　使用控制结构
　　　　嵌套控制结构可以把控制结构放入另一个控制结构之内（例如在 For...Next 循环中的If...Then 块）。一个控制结构内部包含另一个控制结构叫做 nest（嵌套）。在 Visual Basic 中，控制结构的嵌套层数没有限制。按一般习惯，为了使判定结构和循环结构更具可读性，总是用缩排方式书写判定结构或循环的正文部分。
　　　　例如，下面的过程要把打印机和屏幕共有的字体名全部打印出来：
　　　　Private Sub Form_Click ()
　　　　　　　Dim SFont, PFont
　　　　　　　For Each SFont In Screen.Fonts ()
　　　　　　　　　For Each PFont In Printer.Fonts ()
　　　　　　　　　　　If SFont = PFont Then
　　　　　　　　　　　　　Print SFont
　　　　　　　　　　　End If
　　　　　　　　　Next PFont
　　　　　　　Next SFont
　　　　End Sub
　　　　注意，第一个 Next 关闭了内层的 For 循环，而最后一个 For 关闭了外层的 For 循环。同样，在嵌套的 If 语句中，End If 语句自动与最靠近的前一个 If 语句配对。嵌套的 Do...Loop 结构的工作方式也是一样的，最内圈的 Loop 语句与最内圈的 Do 语句匹配。

　　　　 退出控制结构
　　　　用 Exit 语句可以直接退出 For 循环、Do 循环、子过程或函数过程。Exit 语句的语法很简单：Exit For 在 For 循环中出现的次数没有限制，Exit Do 在Do 循环中出现的次数也没有限制。
　　　　For counter = start To end
　　　　　　[Step increment]
　　　　　　[statementblock]
　　　　　　[Exit For]
　　　　　　[statementblock]
　　　　Next [counter[, counter] [,...]]
　　　　Do [{While | Until} condition]
　　　　　　[statementblock]
　　　　　　[Exit Do]
　　　　　　[statementblock]

　　　　Loop
　　　　Exit Do 语句可以在 Do 循环语法的所有版本中使用。
　　　　Exit For 和 Exit Do 非常有用，因为它有时适于立即退出循环，而且不再执行循环中的任何进一步迭代或者语句。例如，在前面的打印屏幕和打印机共有字体的例子中，程序不断将打印机字体和给定的屏幕字体作比较，甚至在已经找到了一个相符的打字机字体后还在继续寻找。对这个函数有一个效率更高的改进版，在此，只要找到相匹配的字体后就立即退出循环：
　　　　Private Sub Form_Click ()
　　　　　　Dim SFont, PFont
　　　　　　For Each SFont In Screen.Fonts ()
　　　　　　　　For Each PFont In Printer.Fonts ()
　　　　　　　　　　If SFont = PFont Then
　　　　　　　　　　　　Print Sfont
　　　　　　　　　　　　Exit For　　　　　　　　'退出内圈循环。
　　　　　　　　　　End If
　　　　　　　　Next PFont
　　　　　　Next SFont
　　　　End Sub
　　　　正如此例所表明的， Exit 语句几乎总是出现在 If 语句或 Select Case 语句内部，而 If 语句或 Select Case 语句在循环内嵌套。
　　　　用 Exit 语句中断循环时，计数器变量的值会因退出循环的方式而不同：
　　　　1.在完成循环时，计数器的值等于上限值加上步进值。
　　　　2.在提前退出循环时，计数器变量保持其值，并遵从有关取值范围的一般规则。
　　　　3.在集合之外叠代时，如果计数器变量为 Object 类型，则其值为Nothing；如果计数器变量为 Variant 类型，则其值为 Empty。

　　　　退出子过程或函数过程
　　　　也可从控制结构内部退出过程。Exit Sub 和 Exit Function 的语法，和上一节“退出控制结构”中的 Exit For 和 Exit Do 相似。Exit Sub 可以出现在子过程主体内的任何地方，出现的次数随需要而定。
　　　　当过程已完成每个任务并可直接返回时，Exit Sub 和 Exit Function 是非常有用的。例如，如果想改动前面的例子，使得对查找到的打印机和屏幕的共有字体，只打印其中的第一个，则可用 Exit Sub ：
　　　　Private Sub Form_Click ()
　　　　　　　Dim SFont, PFont
　　　　　　　For Each SFont In Screen.Fonts ()
　　　　　　　　　For Each PFont In Printer.Fonts ()
　　　　　　　　　　　If SFont = PFont Then
　　　　　　　　　　　　　　Print Sfont
　　　　　　　　　　　　　　Exit Sub　　　　　　　　　　'退出过程。
　　　　　　　　　　　End If
　　　　　　　　　Next PFont
　　　　　　　Next SFont
　　　　End Sub